overte/flake.nix at master · overte-org/overte · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs?ref=nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };
  outputs =
    inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } (
      { inputs, ... }:
      {
        systems = [
          "x86_64-linux"
          "aarch64-linux"
          "aarch64-darwin"
        ];

        perSystem =
          {
            pkgs,
            lib,
            self',
            inputs',
            ...
          }:
          {
            packages = {
              glad = pkgs.callPackage ./nix/glad.nix { };
              etc2comp = pkgs.callPackage ./nix/etc2comp.nix { };

              cgltf = pkgs.callPackage ./nix/cgltf.nix { };

              artery-font-format = pkgs.callPackage ./nix/artery-font-format.nix { };

              gif_creator = pkgs.callPackage ./nix/gif_creator.nix { };

              scribe = pkgs.callPackage ./nix/scribe.nix { };

              overte-full = pkgs.callPackage ./nix/overte.nix {
                inherit (self'.packages)
                  glad
                  scribe
                  gif_creator
                  artery-font-format
                  cgltf
                  etc2comp
                  draco
                  glm
                  ;
                libv8 = pkgs.nodejs_22.libv8;
              };

              # TODO: update/remove when overte updates to more modern version
              draco = pkgs.callPackage ./nix/draco.nix { };

              glm = pkgs.callPackage ./nix/glm.nix { };

              default = self'.packages.overte-full;
            };
            devShells.default = pkgs.mkShell {
              packages = [
                pkgs.conan
                pkgs.ninja
                pkgs.gdb
                pkgs.clang-tools
              ];
              inputsFrom = [ self'.packages.overte-full ];

              buildInputs = [ pkgs.libsForQt5.full ];

              CMAKE_GENERATOR = "Ninja";
              CMAKE_BUILD_TYPE = "Debug";
              CMAKE_EXPORT_COMPILE_COMMANDS = "ON";

              inherit (self'.packages.overte-full)
                NVTT_DIR
                CXXFLAGS
                GLSLANG_DIR
                SCRIBE_DIR
                SPIRV_CROSS_DIR
                SPIRV_TOOLS_DIR
                ;

              shellHook = ''
                # helper for configuring
                configure() {
                    cmake -DOVERTE_USE_SYSTEM_LIBS=ON -B build -S .
                }
              '';
            };
          };
      }
    );
}