ide_jhs/jdoc.ijs at master · jsoftware/ide_jhs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
coclass'jdoc'
coinsert'jhs'

HBS=: 0 : 0
jhclose''
'title'jhtitle'JHS framework'
'jhs locale - utils - verbs/nouns/... for creating apps'
jhbr
mfix '~addons/ide/jhs/form.ijs'
mfix '~addons/ide/jhs/utilh.ijs'
mfix '~addons/ide/jhs/util.ijs'
)

CSS=: 0 : 0
form{margin:10px;}
.defn{white-space:pre;font-family:<PC_FONTFIXED>;color:blue;}
.html1{white-space:pre;font-family:<PC_FONTFIXED>;font-size:200%;border:solid 1px black;}
.html2{white-space:pre;font-family:<PC_FONTFIXED>;font-size:150%;border:solid 1px black;}
.html3{white-space:pre;font-family:<PC_FONTFIXED>;font-size:100%;border:solid 1px black;}
.doc{white-space:pre;font-family:<PC_FONTFIXED>;padding-left:3em;}
)

fix=: 3 : 0
t=. man y
NB. t=. t rplc '<';'&lt;'

NB. mark =: lines
bd=. <;.2 t

NB. NB.*< html
mskhtml=. (<'NB.*.')=5{.each bd
a=. mskhtml#i.#bd
z=. dltb each 5}.each a{bd
class=. {.each z
z=. jhfromax each dltb each }.each z
bd=. ((<'<span class="html'),each class,each (<'">') ,each z,each<'</span>') a}bd

NB. NB.*
msknb=. (-.mskhtml)*.(<'NB.')=3{.each bd
a=. msknb#i.#bd
z=. 4}.each a{bd
z=. jhfromax each z
bd=. ((<'<span class="doc">'),each,z,each<'</span>') a}bd

NB. defn
mskdefn=. -. mskhtml +. msknb
a=. mskdefn#i.#bd
z=. dltb each a{bd
z=. jhfromax each z
bd=. ((<'<span class="defn">'),each,z,each<'</span>') a}bd

t=. ;bd
)

mfix=: 3 : 0
t=. ''jhline''
t=. t,''jhhn 3;y
t=. t,''jhdiv fix y
t
)

jev_get=: 3 : 0
'jdoc'jhr''
)