Layout config with Nix

[georgefst]

For anyone else on NixOS, the following may be of use as a start point for defining complex layouts:

{
  programs.dconf.profiles.user.databases = with pkgs.lib.gvariant; [{
    settings = {
      "org/gnome/shell/extensions/tilingshell" = {
        layouts-json = let inherit (pkgs) lib; in builtins.toJSON (
          let
            grid = xSplits: ySplits:
              let adjacentPairs = l: lib.zipListsWith (start: end: { inherit start end; }) l (lib.tail l); in
              lib.mapCartesianProduct
                ({ x, y }: { x = x.start; y = y.start; width = x.end - x.start; height = y.end - y.start; })
                (builtins.mapAttrs (_: l: adjacentPairs ([ 0 ] ++ l ++ [ 1 ])) { x = xSplits; y = ySplits; });
          in
          lib.imap
            (i: tiles: {
              id = toString i;
              tiles = map (tile: tile // { groups = [ ]; }) tiles;
            }) [
            (grid [ 0.5 ] [ ])
            [
              { x = 0; y = 0; width = 1; height = 0.68; }
              { x = 0; y = 0.68; width = 0.4; height = 0.32; }
              { x = 0.4; y = 0.68; width = 0.6; height = 0.32; }
            ]
            (
              let
                mainWidth = 0.758;
                hiddenTitlebarHeight = 0.012;
              in
              [
                { x = 0; y = 0; width = mainWidth; height = 1; }
                { x = mainWidth; y = 0.00; width = 1 - mainWidth; height = 0.25; }
                { x = mainWidth; y = 0.25; width = 1 - mainWidth; height = 0.25; }
                { x = mainWidth; y = 0.50; width = 1 - mainWidth; height = 0.25; }
                {
                  x = mainWidth;
                  y = 0.75 - hiddenTitlebarHeight;
                  width = 1 - mainWidth;
                  height = 0.25 + hiddenTitlebarHeight;
                }
              ]
            )
            (grid [ 0.27 ] [ ])
            (grid [ 0.5 ] [ 0.5 ])
            ([
              { height = 0.5; width = 0.5; x = 0; y = 0; }
              { height = 0.5 + 0.014; width = 0.5; x = 0; y = 0.5 - 0.014; }
              { height = 0.5; width = 0.5; x = 0.5; y = 0; }
              { height = 0.5; width = 0.5; x = 0.5; y = 0.5; }
            ])
            (grid [ 0.33333 0.66667 ] [ 0.33333 0.66667 ])
            (grid [ 0.25 0.50 0.75 ] [ 0.25 0.50 0.75 ])
            (grid [ 0.2 0.4 0.6 0.8 ] [ 0.2 0.4 0.6 0.8 ])
          ]
        );
      };
    };
  }];
}