livecoding/241228.scd at main · byulparan/livecoding · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168

// ================================================================================
// Ensure Server Boot
s.boot;


(
// ================================================================================
// Everything In Its Right Place - Radiohead
// Cover in SuperCollider
//

// ================================================================================
// Setup
// ================================================================================


TempoClock.tempo_(123/60);

SynthDef(\kick, {
  var freq = XLine.kr(220, 20, 0.1);
  var sig = SinOsc.ar(freq, 0, Line.kr(0.3, 0, 0.2, doneAction: Done.freeSelf));
  Out.ar(0, Pan2.ar(sig));
}).add;

SynthDef(\keyboard, {|freq = 440, dur = 1.0, amp= 0.1|
  var env = EnvGen.kr(Env([0,1,1,0], dur*[0, 0.8, 0.2]), doneAction: Done.freeSelf);
  var mod = SinOsc.ar(freq, 0, 1.6);
  var sig = SinOsc.ar(freq + [0, 1], mod, env*amp);
  Out.ar(0, sig);
}).add;


b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");
~bus = Bus.audio(s, 2);

{
  CombN.ar(In.ar(~bus, 2), 2.0, TempoClock.tempo.reciprocal * [0.25, 1/3], 3.0);
}.play(target: 0, addAction: \addToTail);


Ndef(\voice)[0] = {
  var local = LocalBuf(256);
  var trig = \trig.tr(0);
  var startPos = (BufFrames.kr(b) / 16) * \pos.kr(0);
  var src = PlayBuf.ar(1, b, \rate.kr(1), startPos: startPos, trigger: trig);
  var env = Env([0,1,1,0], \dur.kr(1) * (TempoClock.tempo.reciprocal) * [0.0,0.8,0.2]).kr(0, trig);
  var chain = FFT(local, src * env);
  var sig;
  chain = PV_Freeze(chain, \freeze.kr(0));
  sig = Pan2.ar(IFFT(chain) * Env.asr(4,0.8,4).kr(0, \fade.kr(0)), \pan.kr(0.0));
  Out.ar(~bus, sig*\del.kr(0));
  sig;
};

Ndef(\voice).set(\fade, 0);

Ndef(\voice)[1] = \set->Pbind(
  \freeze, Pif(0.75.loop.coin, 0, 1),
  \pos, Pstep(Pif(0.85.loop.coin, Ptime() * 1.3 % 12, Pwhite(3, 8)), 0.5),
  \rate, Pstep(Prand([0.75, 1.0],inf), 0.5),
  \pan, Pif(0.7.loop.coin, 0.0, Pwhite(-1.0, 1.0)),
  \del, Pif(0.9.loop.coin, 0, 0.3),
  \dur, Pstep(Prand([0.5, 0.5, 0.25, 0.125], inf), 0.5)
);


// ================================================================================
// Performance
// ================================================================================


Routine{

  // ================================================================================
  // define function for play score
  var playScore = {|notes, beatsArray|
	beatsArray.do{|beats, indx|
	  beats.do{|beat|
		notes[indx].do{|note|
		  s.bind({ Synth(\keyboard, [\freq, note.midicps, \dur, beat*0.6]) });
		};
		beat.wait;
	  }
	};
  };

  var playArp = {|notes|
	notes.do{|note|
	  if(note.notNil, {
		s.bind({ Synth(\keyboard, [\freq, note.midicps, \dur, 0.5]) });
	  });
	  0.5.wait;
	}
  };


  // ================================================================================
  // play Music
  playArp.([60,56,55,48]);


  // ================================================================================
  // play kick and voice
  fork{
	Ndef(\voice).set(\fade, 0);
	20.wait;
	Ndef(\voice).play;
	Ndef(\voice).set(\fade, 1);

	inf.do{
	  s.bind({ Synth(\kick) });
	  1.0.wait;
	}
  };


  // ================================================================================
  // Part.1
  7.do{|i|
	var notes = [[36, 48, 52, 55, 60],[37, 49, 53, 55, 60], [39, 51, 55, 60]];
	var beats = [[1.5, 1, 1], [1, 1], [1, 1.5]];

	playScore.(notes, beats);
	playArp.(if(i % 2 == 0, { [60,58,60,48] }, { [60,56,55,48] }));
  };

  inf.do{
	// ================================================================================
	// Part.2
	4.do{|i|
	  var notes = [[41, 53, 57, 60], [36, 48, 52, 55, 60], [37, 49, 53, 55, 60],  [39, 51, 55, 60]];
	  var beats = [[1.5], [1, 1], [1, 1], [1, 1.5]];

	  playScore.(notes, beats);
	  playArp.(if(i != 3, { [60,58,60,48] }, { [60,56,55,48] }));
	};

	// ================================================================================
	// Part.1
	4.do{|i|
	  var notes = [[36, 48, 52, 55, 60],[37, 49, 53, 55, 60], [39, 51, 55, 60]];
	  var beats = [[1.5, 1, 1], [1, 1], [1, 1.5]];

	  playScore.(notes, beats);
	  playArp.(if(i != 3, { [60,56,55,48] }, { [60,58,60,nil]  } ));
	};

	// ================================================================================
	// Part.3
	1.do{
	  var notes = [[37, 49, 53, 56, 60], [36, 48, 52, 55, 60], [39, 51, 55, 58, 60], [39, 51, 55, 58, 61]];

	  playScore.(notes, [[2, 1.5, 1],  [1, 1], [1], [1]]);

	  2.do{
		playScore.(notes, [[1.5, 2, 1.5, 1], [1, 1], [1], [1]]);
	  };

	  playScore.(notes, [[1.5, 2, 1.5, 1], [1, 1], [1, 1.5]]);
	};
  }

}.play;
)