thank you for the plugin. Dont see any resource using Gradle 8.3

[aleon1220]

Hello,
thanks for the plugin. I am not sure what i am doing wrong. I can successfully execute gradle wsdl2java but when i go to the output directory $buildDir/generated/sources/wsdl2java/java i cannot see any java files.

Please find the build.gradle.kts file below

import org.gradle.api.tasks.testing.logging.TestLogEvent
/*
 * file generated by Gradle 'init' task. @Incubating APIs subject to change
 */

plugins {
    java
    // id ("com.adarshr.test-logger") version "3.0.0"
    // https://docs.gradle.org/7.3/dsl/org.gradle.api.tasks.bundling.War.html
    war
    id ("jacoco")
    id("com.github.bjornvester.wsdl2java") version "2.0.2"
}

repositories {
    gradlePluginPortal()
    google()
    mavenCentral()
}

dependencies {
    implementation("org.primefaces.extensions:primefaces-extensions:6.0.0")
    implementation("org.primefaces:primefaces:6.0")
    implementation("com.sun.faces:jsf-api:2.2.12")
    implementation("com.sun.faces:jsf-impl:2.2.12")
    implementation("javax.json:javax.json-api:1.1")
    implementation("javax.ws.rs:javax.ws.rs-api:2.1")
    implementation("com.sun.jersey:jersey-client:1.19.4")
    implementation("com.google.code.gson:gson:2.8.9")
    implementation("org.apache.httpcomponents:httpclient:4.5.3")
    implementation("org.glassfish.jersey.core:jersey-common:2.22.2")
    implementation("javax.servlet:javax.servlet-api:3.1.0")
    // https://mvnrepository.com/artifact/com.google.zxing/javase
    implementation("com.google.zxing:javase:3.5.1")
    implementation("com.google.zxing:core:3.5.1")
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.7.0")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.7.0")
    testImplementation("io.jsonwebtoken:jjwt:0.7.0")
    // dependency below only needed if using the Java 8 version of @Generated (through "jdk8") on Java 9 or later
    implementation("javax.annotation:javax.annotation-api:1.3.2")
    implementation("io.github.threeten-jaxb:threeten-jaxb-core:2.1.0") // Use Java Date/Time API instead of clunky GregorianCalendar class
}

group = "soa.nz.aut"
version = "0.0.1"
description = "Student Attendance WebApp"
java.sourceCompatibility = JavaVersion.VERSION_1_8

tasks.war {
    archiveBaseName.set("Attendance")
    webAppDirectory.set(file("src/main/webapp"))
    // from("src/rootContent") // adds a file-set to the root of the archive
    // webInf { from("src/additionalWebInf") } // adds a file-set to the WEB-INF dir.
    // classpath(fileTree("additionalLibs")) // adds a file-set to the WEB-INF/lib dir.
    // classpath(moreLibs) // adds a configuration to the WEB-INF/lib dir.
    // webXml = file("src/someWeb.xml") // copies a file to WEB-INF/web.xml
}

tasks {
    named<JacocoReport>("jacocoTestReport") {
        reports {
        }
    }
    test {
        useJUnitPlatform()
        testLogging.events = setOf(TestLogEvent.FAILED, TestLogEvent.PASSED, TestLogEvent.SKIPPED)
    }
}

tasks.register<Test>("singleTest") {
    group = "Verification"
    description = "Runs a test to create a local QR code"
    filter {
        includeTestsMatching("utilities.TestQRFunctions.createQRCodeLocally")
    }
}
// https://plugins.gradle.org/plugin/com.github.bjornvester.wsdl2java
// https://www.w3schools.com/xml/tempconvert.asmx?WSDL
wsdl2java {
    wsdlDir.set(layout.projectDirectory.dir("src/main/resources/wsdl"))
    bindingFile.set(layout.projectDirectory.file("src/main/bindings/bindings.xjb"))

    includes.set(
        listOf(
        "src/main/resources/wsdl/NumberConversion.wsdl"
        )
    )
    // includesWithOptions.set(
    //     mapOf(
    //         "**/ServiceTemp.wsdl" to listOf("-wsdlLocation", "https://www.w3schools.com/xml/tempconvert.asmx?WSDL")
    //     )
    // )
    // default output directory $buildDir/generated/sources/wsdl2java/java
}

[freafrea]

This is something I struggled a lot, but it seems that you need to provide includes assuming wsdlDir is already the root. So it should ne just NumberConversion.wsdl

Unfortunately the plugin does not fail if it is unable to find listed files.

[aleon1220]

I need to test this. thank you