InputSender does not trigger Control._get_drag_data() for drag-and-drop gestures

[allan-simon]

Versions

(list all versions where you have replicated the bug)

• Godot: 4.6 beta 1 (both headless and normal)
• GUT: branch godot 4.6
• OS: Linux Ubuntu 22.04

The Bug

Steps To Reproduce

1. Copy all files from this bug_report_gut folder to your Godot project:

   • simple_drag_test.tscn - Minimal test scene
   • simple_draggable.gd - Draggable ColorRect
   • simple_slot.gd - Drop target PanelContainer
   • test_minimal_drag.gd - GUT test

2. Ensure GUT is installed in addons/gut/

Run the Test

Headless mode:

godot --headless -d -s addons/gut/gut_cmdln.gd -gdir=res://bug_report_gut -gtest=test_minimal_drag.gd -gexit

With GUI:

godot -d -s addons/gut/gut_cmdln.gd -gdir=res://bug_report_gut -gtest=test_minimal_drag.gd -gexit

• _get_drag_data() is never called
• _can_drop_data() is never called
• _drop_data() is never called
• Item remains in original slot (Slot1)
• No drag gesture is detected by Godot

But when running manually:

   !!! _get_drag_data CALLED !!!
   _can_drop_data called
   !!! _drop_data CALLED !!!

What else I tested :

# Approach 1: Input singleton
var sender = InputSender.new(Input)

# Approach 2: Viewport
var sender = InputSender.new(get_viewport())

# Approach 3: Control node directly
var sender = InputSender.new(control_node)

[allan-simon]

also I tried "hold_for" but it seems to work only with keyboard press events not mouse events

[allan-simon]

a follow up:

if i bypass gut input sender i can make it to work

extends GutTest

var scene: Control

func before_each():
    var scene_resource = load("res://tests/simple_drag_test.tscn")
    scene = scene_resource.instantiate()
    add_child_autofree(scene)
    await wait_physics_frames(2)

func test_drag_with_viewport_push_input():
    gut.p("=== Testing with viewport.push_input() ===")

    var item = scene.get_node("Slot1/Item")
    var viewport = scene.get_viewport()

    # CRITICAL: Notify viewport that mouse entered
    viewport.notification(Viewport.NOTIFICATION_VP_MOUSE_ENTER)
    await wait_physics_frames(1)

    # Mouse button down
    var mb_down = InputEventMouseButton.new()
    mb_down.button_index = MOUSE_BUTTON_LEFT
    mb_down.pressed = true
    mb_down.position = Vector2(100, 150)
    viewport.push_input(mb_down, true)  # true = local coordinates
    await wait_physics_frames(2)

    # Mouse motion (exceeds drag threshold)
    var mm = InputEventMouseMotion.new()
    mm.position = Vector2(120, 150)
    mm.relative = Vector2(20, 0)
    mm.button_mask = MOUSE_BUTTON_MASK_LEFT
    viewport.push_input(mm, true)
    await wait_physics_frames(1)

    # Continue motion to target
    for x in range(130, 301, 10):
        mm = InputEventMouseMotion.new()
        mm.position = Vector2(x, 150)
        mm.relative = Vector2(10, 0)
        mm.button_mask = MOUSE_BUTTON_MASK_LEFT
        viewport.push_input(mm, true)
        await wait_physics_frames(1)

    # Mouse button up
    var mb_up = InputEventMouseButton.new()
    mb_up.button_index = MOUSE_BUTTON_LEFT
    mb_up.pressed = false
    mb_up.position = Vector2(300, 150)
    viewport.push_input(mb_up, true)
    await wait_physics_frames(5)

    # Verify drag-and-drop worked
    assert_eq(item.get_parent().name, "Slot2", "Item should have moved to Slot2")

The keypoints

it seems Input.parse_input_event only trigger _input and not _gui_input (used for drag and drop)

Note: i needed to add the second parameter true to viewport.push_input otherwise on my multi-screen setup , the position were global not relative to my current screen

I needed to add viewport.notification(Viewport.NOTIFICATION_VP_MOUSE_ENTER)

Proposed fix

I don't know the implication of this "fix" so I just put it here

### Suggested Fix

```gdscript
# Modified input_sender.gd
var _viewport: Viewport = null
var _mouse_entered: bool = false

func _init(target):
    if target is Viewport:
        _viewport = target
    else:
        _viewport = target.get_viewport()

func send_event(event):
    if not _viewport:
        push_error("InputSender: No viewport available")
        return

    # Ensure viewport knows mouse is inside (needed for GUI input)
    if not _mouse_entered:
        _viewport.notification(Viewport.NOTIFICATION_VP_MOUSE_ENTER)
        _mouse_entered = true

    # Use viewport.push_input() instead of Input.parse_input_event()
    # Pass true for local coordinates
    _viewport.push_input(event, true)

[bitwes]

I don't see bug_report_gut attached. Do you still have a copy of it?

[allan-simon]

bug_report_gut.zip

sorry, here you are